F#中的事件（上）-白红宇

.NET中事件的应用

事件是.NET中一个非常重要的概念。在WinForm和WebForm的开发中，事件的使用是极为常见的。比如下面这个简单的例子：

C# Code - 添加事件处理函数
[STAThread]
static void Main()
 { 
     Form form = new Form()
     { 
         Text = "Click Example",
         TopMost = true,
         Visible = true
     };
     EventHandler handler = new EventHandler(form_Click);
     form.Click += handler;
     form.Show();
     Application.Run(form);
 }
static void form_Click(object sender, EventArgs e)
 { 
     MessageBox.Show("Clicked me!");
 }

这里为窗体的Click事件添加了一个处理函数，此过程是通过委托完成的。我们知道，通过+=操作符可以添加一个处理函数，而通过-=则可以移除处理函数。在F#可以这么做：

F# Code - 添加事件处理函数
open System
open System.Windows.Forms
let form_Click (sender: obj) (e: EventArgs) =
     MessageBox.Show("Clicked me!") |> ignore
let form = new Form(
             Text = "Click Example",
             TopMost = true,
             Visible = true)
let handler = new EventHandler(form_Click)
 form.Click.AddHandler handler
 form.Show()
 [<STAThread>]
do Application.Run(form)

可以看到，添加事件处理函数的方式大致相同，即通过AddHandler方法（对应的，也存在一个RemoveHandler方法来移除处理函数）。这种方式是相当“命令式”的。

理解IEvent接口

现在来看看上面的例子，form.Click的信息是：

F# Signature Info
val it : IEvent<EventHandler,EventArgs> = FSI_0003+it@5

但它应该是：

C# Signature Info
public event EventHandler Click;

才对啊！事实上，F#自动将事件转换为了IEvent<EventHandler, EventArgs>，IEvent则继承了IDelegateEvent。它们的基本信息是：

F# Signature Info
type IDelegateEvent<'del when 'del :> System.Delegate > =
abstract AddHandler: 'del -> unit
    abstract RemoveHandler: 'del -> unit
type IEvent<'Del,'T when 'Del : delegate<'T,unit> and 'del :> System.Delegate > =
    abstract Add: event:('T -> unit) -> unit
    inherit IDelegateEvent<'del>

IDelegateEvent提供了前面提到的AddHandler和RemoveHandler方法，它们的用法跟C#中的+=、-=操作符类似。IEvent的Add方法看起来有些奇怪，它是这样使用的：

F# Code - IEvent.Add方法
form.Click.Add(fun _ -> MessageBox.Show("Clicked me again!") |> ignore)

到这里，我们可以了解到在F#中如何以“命令式”的方式添加和移除事件处理函数了，现在你一定想知道F#还有什么是独特而吸引人的呢？

事件是可组合的一等公民

这句话可以分为两部分来理解，首先IEvent的出现使得事件成为了一等公民，也就是说，可以像其它值那样进行传递；然后，多个事件可以进行组合处理。

要做到这两点，我们要借助于Event模块（module）的一些组合子（combinator）成员，比如：

filter：对指定事件进行“过滤”，返回一个新的事件，新事件仅在条件满足时才会触发；

listen：侦听事件，在事件触发时执行指定函数；

map：根据指定的函数对事件进行“转换”，返回一个新的事件。

先来看看这三个方法组合起来的作用：

F# Code - Event基本组合函数
form.MouseDown
|> Event.map (fun args -> (args.X, args.Y))
|> Event.filter (fun (x, y) -> x > 100 && y > 100)
|> Event.listen (fun (x, y) -> printfn "(%d, %d)" x y)

MouseDown的第二个参数是MouseEventHandler类型，但现在我们只关心它的两个坐标值，于是使用map方法对该事件进行转换；到了filter方法这里，我们不希望该事件总是触发，进行过滤，只有当横纵坐标都大于100时才会触发；最后使用listen方法指定事件处理函数。整个过程非常清晰。

choose：一定程度上可以理解为filter和map的组合。

F# Code - Event.choose方法
form.MouseDown
|> Event.choose (fun args ->
if args.X > 100 && args.Y > 100 then Some(args.X, args.Y)
else None)
|> Event.listen (fun (x, y) -> printfn "(%d, %d)" x y)

这段代码的功能跟上段代码是一样的。现在来看一个更有意思的方法merge：

merge：将两个事件“合并”在一起。

F# Code - Event.merge方法
form.MouseDown
|> Event.merge form.MouseMove
|> Event.filter (fun args -> args.Button = MouseButtons.Left)
|> Event.map (fun args -> (args.X, args.Y))
|> Event.listen (fun (x, y) -> printfn "(%d, %d)" x y)

当发生了MouseDown或者MouseMove，并且按下的是左键时就会执行指定的函数。在F#中，我们不仅可以合并两个事件，还可以将一个事件进行分解：

partition：通过指定的谓词函数将事件分解为两个事件，当谓词函数返回true时，触发第一个事件，否则触发第二个事件。

F# Code - Event.partition方法
let (overEvent, underEvent) =
     form.MouseMove
|> Event.merge form.MouseDown
|> Event.filter (fun args -> args.Button = MouseButtons.Left)
|> Event.map (fun args -> (args.X, args.Y))
|> Event.partition (fun (x, y) -> x > 100 && y > 100)
 overEvent |> Event.listen (fun (x, y) -> printfn "Over (%d, %d)" x y)
 underEvent |> Event.listen (fun (x, y) -> printfn "Under (%d, %d)" x y)

如果横纵坐标都大于100的话，将触发overEvent，否则就会触发underEvent。

小结

在.NET开发中，事件以及基于事件的编程是颇为重要的概念，它得到了该平台下各种语言的支持。而F#将事件视为一等公民，这个特性使得我们可以通过更为有趣的方式对事件进行组合处理。

参考

本文转自一个程序员的自省博客园博客，原文链接：http://www.cnblogs.com/anderslly/archive/2009/08/19/composable-events-in-fsharp-part1.html，如需转载请自行联系原作者。